10 REM ----- SPRITE DEMO -----
15 PRINT"[147][144]"
16 POKE 53281,1
20 REM ----- SET UP -----
22 V=53248     : REM VIC CHIP START ADD
23 REM ----- PICTURE -----
24 B=200       : REM BLOCK NUMBER
26 POKE 2040,B : REM POKE BLOCK 200
28 GOSUB 200   : REM STORE PICTURE
30 REM ----- ENABLE SPRITE 0 -----
32 POKE V+21,1 : REM TURN ON SPRITE 0
34 POKE V+39,0 : REM COLOUR IT BLACK
40 REM ----- USE TO SPRITE -----
42 FOR P=1 TO 200
44 POKE V+0,P  : REM X POSITION
45 POKE V+1,P  : REM Y POSITION
49 NEXT P
50 FOR I = 7 TO 0 STEP -1
55 POKE V+39,I : REM ALL COLOURS
60 FOR T =1 TO 1000: NEXT T
65 NEXT I
70 POKE V+29,1 : REM FAT SPRITE
71 GOSUB 100
72 POKE V+23,1 : REM FAT AND TALL
73 GOSUB 100
74 POKE V+29,0 : REM TALL ONLY
75 GOSUB 100
76 POKE V+23,0 : REM SMALL AGAIN
77 GOSUB 100
90 POKE V+21,0 : REM TURN SPRITE OFF
96 LIST 300-
100 FOR T=1 TO 1000:NEXT T: RETURN
200 REM ----- STORY SPRITE -----
201 L=0:PRINT"PLEASE WAIT"
202 FOR I = 0 TO 20: READ R$
206 FOR J=0 TO 2:S$=MID$(R$,J*8+2,8)
210 N=0:P=128
215 FOR K=1 TO 8:D$=MID$(S$,K,1)
220 IF D$="*"THEN N=N+P
225 P=P/2:NEXT K
230 POKE B*64+L,N:L=L+1
280 NEXT J,I:PRINT"[147]"
299 RETURN
300 REM  ------------------------
301 DATA!         ****           !
302 DATA!         *  *           !
303 DATA!        **  **    **    !
304 DATA!        **  **   ***    !
305 DATA!         *  *    ***    !
306 DATA!         ****     *     !
307 DATA!          **      *     !
308 DATA!          **      *     !
309 DATA!    ***************     !
310 DATA!    *   ******          !
311 DATA!    *   ******          !
312 DATA!    *    ****           !
313 DATA!   ***   ****           !
314 DATA!   ***    **            !
315 DATA!   **     **            !
316 DATA!         ****           !
317 DATA!         ****           !
318 DATA!         *  *           !
319 DATA!         *  *           !
320 DATA!     *****  *****       !
321 DATA!     *****  *****       !
322 REM  ------------------------